blob: e2b59bdb115abb7b9d50d84b82e3433dff8eff3c (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
{ stdenv, fetchurl, unzip, jre, coreutils, makeDesktopItem }:
stdenv.mkDerivation rec {
name = "basex-8.3.1";
src = fetchurl {
url = "http://files.basex.org/releases/8.3.1/BaseX831.zip";
sha256 = "08ba0qvfaa1560hy0nsiq9y6slgdj46j9rdssigf2vvkc5ngkgg0";
};
buildInputs = [ unzip jre ];
desktopItem = makeDesktopItem {
name = "basex";
exec = "basexgui %f";
icon = "${./basex.svg}"; # icon copied from Ubuntu basex package
comment = "Visually query and analyse your XML data";
desktopName = "BaseX XML Database";
genericName = "XML database tool";
categories = "Development;Utility;Database";
mimeType = "text/xml";
};
# We're using a pre-built package
configurePhase = "true";
buildPhase = "true";
installPhase = ''
mkdir -p "$out"
cp -r * "$out"
# Remove Windows batch files (unclutter $out/bin)
rm -f "$out"/bin/*.bat
# Move some top-level stuff to $out/share/basex (unclutter $out)
mkdir -p "$out/share/basex"
mv "$out"/*.txt "$out/share/basex/"
mv "$out"/webapp "$out/share/basex/"
# Remove empty directories
rmdir "$out/repo"
rmdir "$out/data"
# Install desktop file
mkdir -p "$out/share/applications"
cp "$desktopItem"/share/applications/* "$out/share/applications/"
# Use substitutions instead of wrapper scripts
for file in "$out"/bin/*; do
sed -i -e "s|/usr/bin/env bash|${stdenv.shell}|" \
-e "s|java|${jre}/bin/java|" \
-e "s|readlink|${coreutils}/bin/readlink|" \
-e "s|dirname|${coreutils}/bin/dirname|" \
-e "s|basename|${coreutils}/bin/basename|" \
-e "s|echo|${coreutils}/bin/echo|" \
"$file"
done
'';
meta = with stdenv.lib; {
description = "XML database and XPath/XQuery processor";
longDescription = ''
BaseX is a very fast and light-weight, yet powerful XML database and
XPath/XQuery processor, including support for the latest W3C Full Text
and Update Recommendations. It supports large XML instances and offers a
highly interactive front-end (basexgui). Apart from two local standalone
modes, BaseX offers a client/server architecture.
'';
homepage = http://basex.org/;
license = licenses.bsd3;
platforms = platforms.linux;
maintainers = [ maintainers.bjornfor ];
};
}
|