blob: 9820e6ac00d47ca7245bd8d50f658f080a96cad8 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
{ lib
, stdenv
, python3Packages
, fetchFromGitHub
, makeWrapper
}:
stdenv.mkDerivation rec {
pname = "bpytop";
version = "1.0.66";
src = fetchFromGitHub {
owner = "aristocratos";
repo = pname;
rev = "v${version}";
sha256 = "sha256-gggsZHKbEt4VSMNTkKGFLcPPt2uHRFDCkqyHYx0c9Y0=";
};
nativeBuildInputs = [ makeWrapper ];
propagatedBuildInputs = with python3Packages; [ python psutil ];
dontBuild = true;
postPatch = ''
sed -i -e "s#/usr/\[local/\]#$out/#g" \
-e "s#/usr/{td}#$out/#g" \
-e "s#THEME_DIR: str = \"\"#THEME_DIR: str = \"$out/share/bpytop/themes\"#" \
./bpytop.py
'';
installPhase = ''
mkdir -p $out/{bin,libexec,share/bpytop}/
cp -r ./themes $out/share/bpytop/
cp ./bpytop.py $out/libexec/
makeWrapper ${python3Packages.python.interpreter} $out/bin/bpytop \
--add-flags "$out/libexec/bpytop.py" \
--prefix PYTHONPATH : "$PYTHONPATH"
'';
meta = with lib; {
description = "A resource monitor; python port of bashtop";
homepage = src.meta.homepage;
license = licenses.apsl20;
maintainers = with maintainers; [ aw ];
platforms = with platforms; linux ++ freebsd ++ darwin;
# https://github.com/NixOS/nixpkgs/pull/94625#issuecomment-668509399
broken = stdenv.isDarwin;
};
}
|