1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
{ stdenv, lib, fetchpatch
, pkg-config, autoreconfHook
, fetchurl, cpio, zlib, bzip2, file, elfutils, libbfd, libgcrypt, libarchive, nspr, nss, popt, db, xz, python, lua, llvmPackages
, sqlite, zstd
}:
stdenv.mkDerivation rec {
pname = "rpm";
version = "4.16.1.3";
src = fetchurl {
url = "http://ftp.rpm.org/releases/rpm-${lib.versions.majorMinor version}.x/rpm-${version}.tar.bz2";
sha256 = "07g2g0adgjm29wqy94iqhpp5dk0hacfw1yf7kzycrrxnfbwwfgai";
};
outputs = [ "out" "dev" "man" ];
nativeBuildInputs = [ autoreconfHook pkg-config ];
buildInputs = [ cpio zlib zstd bzip2 file libarchive libgcrypt nspr nss db xz python lua sqlite ]
++ lib.optionals stdenv.cc.isClang [ llvmPackages.openmp ];
# rpm/rpmlib.h includes popt.h, and then the pkg-config file mentions these as linkage requirements
propagatedBuildInputs = [ popt nss db bzip2 libarchive libbfd ]
++ lib.optional stdenv.isLinux elfutils;
NIX_CFLAGS_COMPILE = "-I${nspr.dev}/include/nspr -I${nss.dev}/include/nss";
configureFlags = [
"--with-external-db"
"--with-lua"
"--enable-python"
"--enable-ndb"
"--enable-sqlite"
"--enable-zstd"
"--localstatedir=/var"
"--sharedstatedir=/com"
];
patches = [
# Small fixes for ndb on darwin
# https://github.com/rpm-software-management/rpm/pull/1465
(fetchpatch {
name = "darwin-support.patch";
url = "https://github.com/rpm-software-management/rpm/commit/2d20e371d5e38f4171235e5c64068cad30bda557.patch";
sha256 = "0p3j5q5a4hl357maf7018k3826jhcpqg6wfrnccrkv30g0ayk171";
})
# Fix build on aarch64-darwin
# https://github.com/rpm-software-management/rpm/pull/1775
(fetchpatch {
url = "https://github.com/emilazy/rpm/commit/45120e756930b4787ea2e06fb8a9e623ea13f2f3.patch";
sha256 = "0zzblwx9apxyjsri4cxd09y9b2hs57r2fck98939j1qgcwy732ar";
})
];
postPatch = ''
substituteInPlace Makefile.am --replace '@$(MKDIR_P) $(DESTDIR)$(localstatedir)/tmp' ""
'';
preFixup = ''
# Don't keep a reference to RPM headers or manpages
for f in $out/lib/rpm/platform/*/macros; do
substituteInPlace $f --replace "$dev" "/rpm-dev-path-was-here"
substituteInPlace $f --replace "$man" "/rpm-man-path-was-here"
done
# Avoid macros like '%__ld' pointing to absolute paths
for tool in ld nm objcopy objdump strip; do
sed -i $out/lib/rpm/macros -e "s/^%__$tool.*/%__$tool $tool/"
done
# Avoid helper scripts pointing to absolute paths
for tool in find-provides find-requires; do
sed -i $out/lib/rpm/$tool -e "s#/usr/lib/rpm/#$out/lib/rpm/#"
done
# symlinks produced by build are incorrect
ln -sf $out/bin/{rpm,rpmquery}
ln -sf $out/bin/{rpm,rpmverify}
'';
meta = with lib; {
homepage = "https://www.rpm.org/";
license = with licenses; [ gpl2Plus lgpl21Plus ];
description = "The RPM Package Manager";
maintainers = with maintainers; [ copumpkin ];
platforms = platforms.linux ++ platforms.darwin;
};
}
|