1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
{ lib, stdenv
, fetchurl
, pkg-config
, glib
, gpm
, file
, e2fsprogs
, libX11
, libICE
, perl
, zip
, unzip
, gettext
, slang
, libssh2
, openssl
, coreutils
, autoreconfHook
, autoSignDarwinBinariesHook
}:
stdenv.mkDerivation rec {
pname = "mc";
version = "4.8.26";
src = fetchurl {
url = "https://www.midnight-commander.org/downloads/${pname}-${version}.tar.xz";
sha256 = "sha256-xt6txQWV8tmiLcbCmanyizk+NYNG6/bKREqEadwWbCc=";
};
nativeBuildInputs = [ pkg-config autoreconfHook unzip ]
# The preFixup hook rewrites the binary, which invaliates the code
# signature. Add the fixup hook to sign the output.
++ lib.optionals (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) [
autoSignDarwinBinariesHook
];
buildInputs = [
file
gettext
glib
libICE
libX11
libssh2
openssl
perl
slang
zip
] ++ lib.optionals (!stdenv.isDarwin) [ e2fsprogs gpm ];
enableParallelBuilding = true;
configureFlags = [ "--enable-vfs-smb" ];
postPatch = ''
substituteInPlace src/filemanager/ext.c \
--replace /bin/rm ${coreutils}/bin/rm
'';
postFixup = ''
# remove unwanted build-dependency references
sed -i -e "s!PKG_CONFIG_PATH=''${PKG_CONFIG_PATH}!PKG_CONFIG_PATH=$(echo "$PKG_CONFIG_PATH" | sed -e 's/./0/g')!" $out/bin/mc
'' + lib.optionalString (!stdenv.isDarwin) ''
# libX11.so is loaded dynamically so autopatch doesn't detect it
patchelf \
--add-needed ${libX11}/lib/libX11.so \
$out/bin/mc
'';
meta = with lib; {
description = "File Manager and User Shell for the GNU Project";
downloadPage = "https://www.midnight-commander.org/downloads/";
homepage = "https://www.midnight-commander.org";
license = licenses.gpl2Plus;
maintainers = with maintainers; [ sander ];
platforms = with platforms; linux ++ darwin;
repositories.git = "https://github.com/MidnightCommander/mc.git";
updateWalker = true;
};
}
|