blob: d8e6b511521a5dbf540d0b35b04c11b2729e0e37 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
{ stdenv
, lib
, buildGoModule
, fetchFromGitHub
, installShellFiles
, buildPackages
, testers
, goreleaser
}:
buildGoModule rec {
pname = "goreleaser";
version = "1.22.0";
src = fetchFromGitHub {
owner = "goreleaser";
repo = pname;
rev = "v${version}";
hash = "sha256-82DaGmXS+qbPN3dg1Zk/WHGOymJEuhOzQl+MsPmi5tw=";
};
vendorHash = "sha256-+ac4q820gETsNRVpW2u0MXU6HfoztLdsWK2HYqJ4mqo=";
ldflags =
[ "-s" "-w" "-X main.version=${version}" "-X main.builtBy=nixpkgs" ];
# tests expect the source files to be a build repo
doCheck = false;
nativeBuildInputs = [ installShellFiles ];
postInstall =
let emulator = stdenv.hostPlatform.emulator buildPackages;
in ''
${emulator} $out/bin/goreleaser man > goreleaser.1
installManPage ./goreleaser.1
installShellCompletion --cmd goreleaser \
--bash <(${emulator} $out/bin/goreleaser completion bash) \
--fish <(${emulator} $out/bin/goreleaser completion fish) \
--zsh <(${emulator} $out/bin/goreleaser completion zsh)
'';
passthru.tests.version = testers.testVersion {
package = goreleaser;
command = "goreleaser -v";
inherit version;
};
meta = with lib; {
description = "Deliver Go binaries as fast and easily as possible";
homepage = "https://goreleaser.com";
maintainers = with maintainers; [
c0deaddict
endocrimes
sarcasticadmin
techknowlogick
developer-guy
caarlos0
];
license = licenses.mit;
};
}
|