blob: 3216790590e1f61bccf16977239ac152b90d0715 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
{ lib
, stdenv
, fetchfossil
, tcl
, enableTcl ? true
}:
stdenv.mkDerivation {
pname = "pikchr";
# To update, use the last check-in in https://pikchr.org/home/timeline?r=trunk
version = "unstable-2023-08-30";
src = fetchfossil {
url = "https://pikchr.org/home";
rev = "d6f80b1ab30654d5";
sha256 = "sha256-GEH1qFiMYmNFJnZzLG5rxpl+F7OSRMoVcdo94+mvrlY=";
};
# can't open generated html files
postPatch = ''
substituteInPlace Makefile --replace open "test -f"
'';
nativeBuildInputs = lib.optional enableTcl tcl.tclPackageHook;
buildInputs = lib.optional enableTcl tcl;
makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];
buildFlags = [ "pikchr" ] ++ lib.optional enableTcl "piktcl";
installPhase = ''
runHook preInstall
install -Dm755 pikchr $out/bin/pikchr
install -Dm755 pikchr.out $out/lib/pikchr.o
install -Dm644 pikchr.h $out/include/pikchr.h
'' + lib.optionalString enableTcl ''
cp -r piktcl $out/lib/piktcl
'' + ''
runHook postInstall
'';
dontWrapTclBinaries = true;
doCheck = true;
meta = with lib; {
description = "A PIC-like markup language for diagrams in technical documentation";
homepage = "https://pikchr.org";
license = licenses.bsd0;
maintainers = with maintainers; [ fgaz ];
platforms = platforms.all;
mainProgram = "pikchr";
};
}
|