1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
{ lib, stdenv, fetchurl
, pkg-config, python3, sphinx
, zstd
, acl, attr, e2fsprogs, libuuid, lzo, udev, zlib
, runCommand, btrfs-progs
, gitUpdater
}:
stdenv.mkDerivation rec {
pname = "btrfs-progs";
version = "5.17";
src = fetchurl {
url = "mirror://kernel/linux/kernel/people/kdave/btrfs-progs/btrfs-progs-v${version}.tar.xz";
sha256 = "sha256-Y7d4/kwrrRjjcdzljtNUiOCPWDkhNnRU/diFB6PQ2J4=";
};
nativeBuildInputs = [
pkg-config
python3 python3.pkgs.setuptools
sphinx
];
buildInputs = [ acl attr e2fsprogs libuuid lzo python3 zlib zstd ] ++ lib.optionals stdenv.hostPlatform.isGnu [ udev ];
# for python cross-compiling
_PYTHON_HOST_PLATFORM = stdenv.hostPlatform.config;
# gcc bug with -O1 on ARM with gcc 4.8
# This should be fine on all platforms so apply universally
postPatch = "sed -i s/-O1/-O2/ configure";
postInstall = ''
install -v -m 444 -D btrfs-completion $out/share/bash-completion/completions/btrfs
'';
configureFlags = lib.optional stdenv.hostPlatform.isMusl "--disable-backtrace --disable-libudev";
makeFlags = lib.optionals stdenv.hostPlatform.isGnu [ "udevruledir=$(out)/lib/udev/rules.d" ];
enableParallelBuilding = true;
passthru.tests = {
simple-filesystem = runCommand "btrfs-progs-create-fs" {} ''
mkdir -p $out
truncate -s110M $out/disc
${btrfs-progs}/bin/mkfs.btrfs $out/disc | tee $out/success
${btrfs-progs}/bin/btrfs check $out/disc | tee $out/success
[ -e $out/success ]
'';
};
passthru.updateScript = gitUpdater {
inherit pname version;
# No nicer place to find latest release.
url = "https://github.com/kdave/btrfs-progs.git";
rev-prefix = "v";
};
meta = with lib; {
description = "Utilities for the btrfs filesystem";
homepage = "https://btrfs.wiki.kernel.org/";
license = licenses.gpl2Only;
maintainers = with maintainers; [ raskin ];
platforms = platforms.linux;
};
}
|