pkgs/tools/audio/mididings/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

{ lib, python2Packages, fetchFromGitHub, pkg-config, glib, alsa-lib, libjack2  }:

python2Packages.buildPythonApplication {
  version = "2015-11-17";
  pname = "mididings";

  src = fetchFromGitHub {
    owner = "dsacre";
    repo = "mididings";
    rev = "bbec99a8c878a2a7029e78e84fc736e4a68ed5a0";
    sha256 = "1pdf5mib87zy7yjh9vpasja419h28wvgq6x5hw2hkm7bg9ds4p2m";
  };

  nativeBuildInputs = [ pkg-config ];
  buildInputs = [ glib alsa-lib libjack2 python2Packages.boost ];
  propagatedBuildInputs = with python2Packages; [ decorator ]
    # for livedings
    ++ [ tkinter pyliblo ]
    # for mididings.extra
    ++ [ dbus-python pyinotify ]
    # to read/write standard MIDI files
    ++ [ pysmf ]
    # so mididings knows where to look for config files
    ++ [ pyxdg ];

  preBuild = with lib.versions; ''
    substituteInPlace setup.py \
      --replace boost_python "boost_python${major python2Packages.python.version}${minor python2Packages.python.version}"
  '';

  meta = with lib; {
    description = "A MIDI router and processor based on Python, supporting ALSA and JACK MIDI";
    homepage = "http://das.nasophon.de/mididings";
    license = licenses.gpl2;
    maintainers = [ ];
    platforms = platforms.linux;
  };
}