pkgs/test/haskell/setBuildTarget/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

{ pkgs, haskellPackages }:

let
  # This can be regenerated by running `cabal2nix .` in the current directory.
  pkgDef =
    { mkDerivation, base, lib }:
      mkDerivation {
        pname = "haskell-setBuildTarget";
        version = "0.1.0.0";
        src = ./.;
        isLibrary = false;
        isExecutable = true;
        executableHaskellDepends = [ base ];
        license = lib.licenses.bsd3;
      };

  drv = haskellPackages.callPackage pkgDef {};

  test  = target: excluded:
    let only = pkgs.haskell.lib.setBuildTarget drv target;
    in ''
         if [[ ! -f "${only}/bin/${target}" ]]; then
           echo "${target} was not built"
           exit 1
         fi

         if [[ -f "${only}/bin/${excluded}" ]]; then
           echo "${excluded} was built, when it should not have been"
           exit 1
         fi
     '';

in pkgs.runCommand "test haskell.lib.setBuildTarget" {} ''
  ${test "foo" "bar"}
  ${test "bar" "foo"}
  touch "$out"
''