blob: fa5783728767400f9dc3bfb5667cbc9399d01567 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
{ stdenv, fetchzip, kernel, perl, wireguard-tools, bc }:
# module requires Linux >= 3.10 https://www.wireguard.io/install/#kernel-requirements
assert stdenv.lib.versionAtLeast kernel.version "3.10";
# wireguard upstreamed since 5.6 https://lists.zx2c4.com/pipermail/wireguard/2019-December/004704.html
assert stdenv.lib.versionOlder kernel.version "5.6";
stdenv.mkDerivation rec {
pname = "wireguard";
version = "1.0.20200729";
src = fetchzip {
url = "https://git.zx2c4.com/wireguard-linux-compat/snapshot/wireguard-linux-compat-${version}.tar.xz";
sha256 = "0fk2i65q8pk11n46a31017059aan7hbbx0xv6d2c9d80dzrw5a36";
};
hardeningDisable = [ "pic" ];
KERNELDIR = "${kernel.dev}/lib/modules/${kernel.modDirVersion}/build";
nativeBuildInputs = [ perl bc ] ++ kernel.moduleBuildDependencies;
preBuild = "cd src";
buildFlags = [ "module" ];
INSTALL_MOD_PATH = placeholder "out";
installFlags = [ "DEPMOD=true" ];
enableParallelBuilding = true;
passthru = {
# remove this when our kernel comes with native wireguard support
# and our tests no longer tests this package
inherit (wireguard-tools) tests;
};
meta = with stdenv.lib; {
inherit (wireguard-tools.meta) homepage license maintainers;
description = "Kernel module for the WireGuard secure network tunnel";
downloadPage = "https://git.zx2c4.com/wireguard-linux-compat/refs/";
platforms = platforms.linux;
};
}
|