blob: 4371efca4f0afb8ce628141b0975eca156d8a1ed (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
{ lib
, stdenv
, rustPlatform
, fetchFromGitHub
, help2man
, installShellFiles
, libiconv
, Security
, CoreServices
, nix-update-script
}:
let
isCross = stdenv.hostPlatform != stdenv.buildPlatform;
in rustPlatform.buildRustPackage rec {
pname = "texlab";
version = "4.2.1";
src = fetchFromGitHub {
owner = "latex-lsp";
repo = pname;
rev = "refs/tags/v${version}";
sha256 = "sha256-za3TauhNoxGDphpY615EnTt46HpMgS+sYpBln/twefw=";
};
cargoSha256 = "sha256-wppaa3IGOqkFu/1CAp8g+PlPtMWm/7qNpPu0k4/mL3A=";
outputs = [ "out" ] ++ lib.optional (!isCross) "man";
nativeBuildInputs = [ installShellFiles ]
++ lib.optional (!isCross) help2man;
buildInputs = lib.optionals stdenv.isDarwin [
libiconv
Security
CoreServices
];
postInstall = ''
# Remove generated dylib of human_name dependency. TexLab statically
# links to the generated rlib and doesn't reference the dylib. I
# couldn't find any way to prevent building this by passing cargo flags.
# See https://github.com/djudd/human-name/blob/master/Cargo.toml#L43
rm "$out/lib/libhuman_name${stdenv.hostPlatform.extensions.sharedLibrary}"
rmdir "$out/lib"
''
# When we cross compile we cannot run the output executable to
# generate the man page
+ lib.optionalString (!isCross) ''
# TexLab builds man page separately in CI:
# https://github.com/latex-lsp/texlab/blob/v4.2.1/.github/workflows/publish.yml#L131-L135
help2man --no-info "$out/bin/texlab" > texlab.1
installManPage texlab.1
'';
passthru.updateScript = nix-update-script {
attrPath = pname;
};
meta = with lib; {
description = "An implementation of the Language Server Protocol for LaTeX";
homepage = "https://texlab.netlify.app";
license = licenses.mit;
maintainers = with maintainers; [ doronbehar kira-bruneau ];
platforms = platforms.all;
};
}
|