blob: c6863d535dd96b488474de8783c623b9bc413c7d (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
{ lib, fetchFromGitHub, rustPlatform, coreutils, bash, installShellFiles }:
rustPlatform.buildRustPackage rec {
pname = "just";
version = "0.9.0";
src = fetchFromGitHub {
owner = "casey";
repo = pname;
rev = "v${version}";
sha256 = "sha256-orHUovyFFOPRvbfLKQhkfZzM0Gs2Cpe1uJg/6+P8HKY=";
};
cargoSha256 = "sha256-YDIGZRbszhgWM7iAc2i89jyndZvZZsg63ADQfqFxfXw=";
nativeBuildInputs = [ installShellFiles ];
postInstall = ''
installManPage man/just.1
installShellCompletion --cmd just \
--bash completions/just.bash \
--fish completions/just.fish \
--zsh completions/just.zsh
'';
checkInputs = [ coreutils bash ];
preCheck = ''
# USER must not be empty
export USER=just-user
export USERNAME=just-user
sed -i src/justfile.rs \
-i tests/*.rs \
-e "s@/bin/echo@${coreutils}/bin/echo@g" \
-e "s@#!/usr/bin/env sh@#!${bash}/bin/sh@g" \
-e "s@#!/usr/bin/env cat@#!${coreutils}/bin/cat@g" \
-e "s@#!/usr/bin/env bash@#!${bash}/bin/sh@g"
'';
# Skip "edit" when running "cargo test", since this test case needs "cat".
# Skip "choose" when running "cargo test", since this test case needs "fzf".
checkFlags = [ "--skip=choose" "--skip=edit" ];
meta = with lib; {
description = "A handy way to save and run project-specific commands";
homepage = "https://github.com/casey/just";
license = licenses.cc0;
maintainers = with maintainers; [ xrelkd ];
};
}
|