pkgs/development/tools/clang-tools/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

{ stdenv, llvmPackages }:

let
  clang = llvmPackages.clang-unwrapped;

in stdenv.mkDerivation {
  pname = "clang-tools";
  version = stdenv.lib.getVersion clang;

  dontUnpack = true;

  installPhase = ''
    runHook preInstall

    mkdir -p $out/bin
    export libc_includes="${stdenv.lib.getDev stdenv.cc.libc}/include"
    export libcpp_includes="${llvmPackages.libcxx}/include/c++/v1"

    export clang=${clang}
    substituteAll ${./wrapper} $out/bin/clangd
    chmod +x $out/bin/clangd
    for tool in \
      clang-apply-replacements \
      clang-check \
      clang-format \
      clang-rename \
      clang-tidy
    do
      ln -s $out/bin/clangd $out/bin/$tool
    done

    runHook postInstall
  '';

  meta = clang.meta // {
    description = "Standalone command line tools for C++ development";
    maintainers = with stdenv.lib.maintainers; [ aherrmann ];
  };
}