blob: 5832d9a069338d11e96cb0bdae447e40ad574880 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
{ lib
, fetchFromGitHub
, fetchNpmDeps
, buildPythonPackage
, nix-update-script
# build-system
, gettext
, nodejs
, npmHooks
, setuptools-scm
# dependencies
, django
# tests
, pytest-django
, pytestCheckHook
}:
buildPythonPackage rec {
pname = "django-hijack";
version = "3.4.2";
format = "setuptools";
src = fetchFromGitHub {
owner = "django-hijack";
repo = "django-hijack";
rev = "refs/tags/${version}";
hash = "sha256-E5gM/5MIB65gdyv/I+Kuw8rbjPvtUnbCPXpasaIDzyo=";
};
postPatch = ''
substituteInPlace setup.py \
--replace 'cmd = ["npm", "ci"]' 'cmd = ["true"]' \
--replace 'f"{self.build_lib}/{name}.mo"' 'f"{name}.mo"'
sed -i "/addopts/d" setup.cfg
'';
npmDeps = fetchNpmDeps {
inherit src;
hash = "sha256-4ZVb+V/oYfflIZdme6hbpoSBFVV7lk5wLfEzzBqZv/Y=";
};
SETUPTOOLS_SCM_PRETEND_VERSION = version;
nativeBuildInputs = [
gettext
nodejs
npmHooks.npmConfigHook
setuptools-scm
];
propagatedBuildInputs = [
django
];
nativeCheckInputs = [
pytestCheckHook
pytest-django
];
env.DJANGO_SETTINGS_MODULE = "hijack.tests.test_app.settings";
pytestFlagsArray = [
"--pyargs" "hijack"
"-W" "ignore::DeprecationWarning"
];
# needed for npmDeps update
passthru.updateScript = nix-update-script { };
meta = with lib; {
description = "Allows superusers to hijack (=login as) and work on behalf of another user";
homepage = "https://github.com/arteria/django-hijack";
changelog = "https://github.com/django-hijack/django-hijack/releases/tag/${version}";
license = licenses.mit;
maintainers = with maintainers; [ ris ];
};
}
|