pkgs/development/libraries/vapoursynth/editor.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

{ lib, mkDerivation, fetchFromBitbucket
, python3, vapoursynth
, qmake, qtbase, qtwebsockets
}:

mkDerivation rec {
  pname = "vapoursynth-editor";
  version = "R19";

  src = fetchFromBitbucket {
    owner = "mystery_keeper";
    repo = pname;
    rev = lib.toLower version;
    sha256 = "1zlaynkkvizf128ln50yvzz3b764f5a0yryp6993s9fkwa7djb6n";
  };

  nativeBuildInputs = [ qmake ];
  buildInputs = [ qtbase vapoursynth qtwebsockets ];

  dontWrapQtApps = true;

  preConfigure = "cd pro";

  preFixup = ''
    cd ../build/release*
    mkdir -p $out/bin
    for bin in vsedit{,-job-server{,-watcher}}; do
        mv $bin $out/bin

        wrapQtApp $out/bin/$bin \
            --prefix PYTHONPATH : ${vapoursynth}/${python3.sitePackages} \
            --prefix LD_LIBRARY_PATH : ${vapoursynth}/lib
    done
  '';

  meta = with lib; {
    description = "Cross-platform editor for VapourSynth scripts";
    homepage = "https://bitbucket.org/mystery_keeper/vapoursynth-editor";
    license = licenses.mit;
    maintainers = with maintainers; [ tadeokondrak ];
    platforms = platforms.all;
  };
}