blob: b08495cae74c3bc65e17fb3ce85b4e911cca2520 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
{ lib
, stdenv
, fetchFromGitHub
, fetchpatch
# build
, cmake
, pkg-config
# runtime
, espeak-ng
, onnxruntime
}:
let
espeak-ng' = espeak-ng.overrideAttrs (oldAttrs: {
version = "1.52-dev";
src = fetchFromGitHub {
owner = "rhasspy";
repo = "espeak-ng";
rev = "0f65aa301e0d6bae5e172cc74197d32a6182200f";
hash = "sha256-2V0D3QO+v9OqffpNmwJQd3NIBd/IFeLkjaJ3Y0HHw7E=";
};
patches = [
(fetchpatch {
url = "https://github.com/espeak-ng/espeak-ng/commit/497c6217d696c1190c3e8b992ff7b9110eb3bedd.patch";
hash = "sha256-KfzqnRyQfz6nuMKnsHoUzb9rn9h/Pg54mupW1Cr+Zx0=";
})
./espeak-mbrola.patch
];
});
in
stdenv.mkDerivation rec {
pname = "piper-phonemize";
version = "2023.11.14-4";
src = fetchFromGitHub {
owner = "rhasspy";
repo = "piper-phonemize";
rev = "refs/tags/${version}";
hash = "sha256-pj1DZUhy3XWGn+wNtxKKDWET9gsfofEB0NZ+EEQz9q0=";
};
nativeBuildInputs = [
cmake
pkg-config
];
cmakeFlags = [
"-DONNXRUNTIME_DIR=${onnxruntime.dev}"
"-DESPEAK_NG_DIR=${espeak-ng'}"
];
buildInputs = [
espeak-ng'
onnxruntime
];
passthru = {
espeak-ng = espeak-ng';
};
meta = with lib; {
description = "C++ library for converting text to phonemes for Piper";
homepage = "https://github.com/rhasspy/piper-phonemize";
license = licenses.mit;
maintainers = with maintainers; [ hexa ];
};
}
|