blob: 991309b54d46de2e16c923ae27a7c0405396f53d (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
{ lib, stdenv, fetchurl, python, makeWrapper }:
stdenv.mkDerivation rec {
pname = "lhapdf";
version = "6.5.1";
src = fetchurl {
url = "https://www.hepforge.org/archive/lhapdf/LHAPDF-${version}.tar.gz";
sha256 = "sha256-ElZBniIn0aT5M4f+HagF5kg1FBfTdV6K9aMKNaamZ1E=";
};
# The Apple SDK only exports locale_t from xlocale.h whereas glibc
# had decided that xlocale.h should be a part of locale.h
postPatch = lib.optionalString (stdenv.isDarwin && stdenv.cc.isGNU) ''
substituteInPlace src/GridPDF.cc --replace '#include <locale>' '#include <xlocale.h>'
'';
nativeBuildInputs = [ makeWrapper ]
++ lib.optionals (python != null && lib.versionAtLeast python.version "3.10") [ python.pkgs.cython ];
buildInputs = [ python ];
configureFlags = lib.optionals (python == null) [ "--disable-python" ];
preBuild = lib.optionalString (python != null && lib.versionAtLeast python.version "3.10") ''
rm wrappers/python/lhapdf.cpp
'';
enableParallelBuilding = true;
passthru = {
pdf_sets = import ./pdf_sets.nix { inherit lib stdenv fetchurl; };
};
postInstall = ''
wrapProgram $out/bin/lhapdf --prefix PYTHONPATH : "$(toPythonPath "$out")"
'';
meta = with lib; {
description = "A general purpose interpolator, used for evaluating Parton Distribution Functions from discretised data files";
license = licenses.gpl2;
homepage = "http://lhapdf.hepforge.org";
platforms = platforms.unix;
maintainers = with maintainers; [ veprbl ];
};
}
|