blob: d87309111d569fb12b348d2930e4d2360f5bfb19 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
{ fetchFromGitHub
, lib
, stdenv
, autoreconfHook
, pkg-config
, gettext
, python3
, texinfo
, help2man
, libyaml
, perl
}:
stdenv.mkDerivation (finalAttrs: {
pname = "liblouis";
version = "3.26.0";
outputs = [ "out" "dev" "info" "doc" ]
# configure: WARNING: cannot generate manual pages while cross compiling
++ lib.optionals (stdenv.hostPlatform == stdenv.buildPlatform) [ "man" ];
src = fetchFromGitHub {
owner = "liblouis";
repo = "liblouis";
rev = "v${finalAttrs.version}";
hash = "sha256-Kko9qBWdNiZ61Wbb7lUYoSNU1hhRUexPcU3pADv0UHo=";
};
strictDeps = true;
nativeBuildInputs = [
autoreconfHook
pkg-config
gettext
python3
# Docs, man, info
texinfo
help2man
];
buildInputs = [
# lou_checkYaml
libyaml
];
nativeCheckInputs = [
perl
];
configureFlags = [
# Required by Python bindings
"--enable-ucs4"
];
postPatch = ''
patchShebangs tests
substituteInPlace python/louis/__init__.py.in --replace "###LIBLOUIS_SONAME###" "$out/lib/liblouis.so"
'';
postInstall = ''
pushd python
python setup.py install --prefix="$out" --optimize=1
popd
'';
doCheck = true;
meta = with lib; {
description = "Open-source braille translator and back-translator";
homepage = "https://liblouis.io/";
license = with licenses; [
lgpl21Plus # library
gpl3Plus # tools
];
maintainers = with maintainers; [ jtojnar ];
platforms = platforms.unix;
};
})
|