blob: 2a9af50fcde98907199b7daf64773fb8b29b1e94 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
{ stdenv, fetchurl, pkgconfig, yasm
, freetype ? null
, fribidi ? null
, encaSupport ? true, enca ? null # enca support
, fontconfigSupport ? true, fontconfig ? null # fontconfig support
, harfbuzzSupport ? true, harfbuzz ? null # harfbuzz support
, rasterizerSupport ? false # Internal rasterizer
, largeTilesSupport ? false # Use larger tiles in the rasterizer
}:
assert ((freetype != null) && (fribidi != null));
assert encaSupport -> (enca != null);
assert fontconfigSupport -> (fontconfig != null);
assert harfbuzzSupport -> (harfbuzz != null);
let
mkFlag = optSet: flag: if optSet then "--enable-${flag}" else "--disable-${flag}";
in
with stdenv.lib;
stdenv.mkDerivation rec {
name = "libass-${version}";
version = "0.12.1";
src = fetchurl {
url = "https://github.com/libass/libass/releases/download/${version}/${name}.tar.xz";
sha256 = "1mwj2nk9g6cq6f8m1hf0ijg1299rghhy9naahqq43sc2whblb1l7";
};
configureFlags = [
(mkFlag encaSupport "enca")
(mkFlag fontconfigSupport "fontconfig")
(mkFlag harfbuzzSupport "harfbuzz")
(mkFlag rasterizerSupport "rasterizer")
(mkFlag largeTilesSupport "large-tiles")
];
nativeBuildInputs = [ pkgconfig yasm ];
buildInputs = [ freetype fribidi ]
++ optional encaSupport enca
++ optional fontconfigSupport fontconfig
++ optional harfbuzzSupport harfbuzz;
meta = {
description = "Portable ASS/SSA subtitle renderer";
homepage = https://github.com/libass/libass;
license = licenses.isc;
platforms = platforms.unix;
maintainers = with maintainers; [ codyopel urkud ];
repositories.git = git://github.com/libass/libass.git;
};
}
|