blob: 9f1048f2de56daf2aac492a292cdba7b16fd69ad (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
{ fetchurl, stdenv, perl, bison, flex, pkgconfig, glib, libxml2, libintl }:
stdenv.mkDerivation rec {
name = "gstreamer-0.10.36";
src = fetchurl {
urls =
[ "${meta.homepage}/src/gstreamer/${name}.tar.xz"
"mirror://gentoo/distfiles/${name}.tar.xz"
];
sha256 = "1nkid1n2l3rrlmq5qrf5yy06grrkwjh3yxl5g0w58w0pih8allci";
};
outputs = [ "out" "dev" ];
nativeBuildInputs = [ pkgconfig libintl ];
buildInputs = [ perl bison flex ];
propagatedBuildInputs = [ glib libxml2 ];
patchPhase = ''
sed -i -e 's/^ /\t/' docs/gst/Makefile.in docs/libs/Makefile.in docs/plugins/Makefile.in
''
+ stdenv.lib.optionalString stdenv.isDarwin ''
# Applying this patch manually to avoid a rebuild on Linux. Feel free to refactor later
# See https://trac.macports.org/ticket/40783 for explanation of patch
patch -p1 < ${./darwin.patch}
'';
configureFlags = [
"--disable-examples"
"--enable-failing-tests"
"--localstatedir=/var"
"--disable-gtk-doc"
"--disable-docbook"
];
postInstall = ''
# Hm, apparently --disable-gtk-doc is ignored...
rm -rf $out/share/gtk-doc
paxmark m $out/bin/gst-launch* $out/libexec/gstreamer-*/gst-plugin-scanner
'';
setupHook = ./setup-hook.sh;
meta = {
homepage = https://gstreamer.freedesktop.org;
description = "Library for constructing graphs of media-handling components";
longDescription = ''
GStreamer is a library for constructing graphs of media-handling
components. The applications it supports range from simple
Ogg/Vorbis playback, audio/video streaming to complex audio
(mixing) and video (non-linear editing) processing.
Applications can take advantage of advances in codec and filter
technology transparently. Developers can add new codecs and
filters by writing a simple plugin with a clean, generic
interface.
'';
license = stdenv.lib.licenses.lgpl2Plus;
platforms = stdenv.lib.platforms.unix;
};
}
|