pkgs/development/libraries/ceres-solver/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

{ stdenv
, eigen
, fetchurl
, cmake
, google-gflags ? null
, glog ? null
, runTests ? false
}:

# google-gflags is required to run tests
assert runTests -> google-gflags != null;

let
  version = "1.10.0";

  # glog currently doesn't build on darwin
  # Issue: https://code.google.com/p/google-glog/issues/detail?id=121
  useGlog = glog != null && !stdenv.isDarwin;

in
stdenv.mkDerivation {
  name = "ceres-solver-${version}";

  src = fetchurl {
    url = "http://ceres-solver.org/ceres-solver-${version}.tar.gz";
    sha256 = "20bb5db05c3e3e14a4062e2cf2b0742d2653359549ecded3e0653104ef3deb17";
  };

  buildInputs = [ cmake ]
    ++ stdenv.lib.optional useGlog glog
    ++ stdenv.lib.optional (google-gflags != null) google-gflags;

  inherit eigen;

  doCheck = runTests;

  checkTarget = "test";

  cmakeFlags = "
    -DEIGEN_INCLUDE_DIR=${eigen}/include/eigen3
    ${if !useGlog then "-DMINIGLOG=ON" else ""}
  ";

  meta = with stdenv.lib; {
    description = "C++ library for modeling and solving large, complicated optimization problems";
    license = licenses.bsd3;
    homepage = "http://ceres-solver.org";
    maintainers = with stdenv.lib.maintainers; [ giogadi ];
    inherit version;
  };
}