blob: 9fe0e42cb138df17882bf4ff0897330290e655f8 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
{ lib
, stdenv
, fetchFromGitHub
, fetchpatch
, testers
, uasm
}:
stdenv.mkDerivation rec {
pname = "uasm";
version = "2.56.2";
src = fetchFromGitHub {
owner = "Terraspace";
repo = pname;
# Specifying only the tag results in the following error during download:
# the given path has multiple possibilities: #<Git::Ref:0x00007f618689c378>, #<Git::Ref:0x00007f618689c1e8>
# Probably because upstream has both a tag and a branch with the same name
rev = "refs/tags/v${version}";
hash = "sha256-QiRBscY6zefeLDDVhS/+j9yIJ+5QhgkDQh1CLl/CslM=";
};
patches = [
(fetchpatch {
name = "fix-v2_55-compilation-on-macos.patch";
url = "https://github.com/Terraspace/UASM/commit/b50c430cc3083c7f32e288a9f64fe1cafb03091d.patch";
sha256 = "sha256-FGFB282LSEKtGD1cIRH+Qi5bye5Gx4xb0Ty4J03xjCU";
})
];
enableParallelBuilding = true;
makefile =
if stdenv.isDarwin then
"ClangOSX64.mak"
else
"gccLinux64.mak";
makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];
installPhase = ''
runHook preInstall
install -Dt "$out/bin" -m0755 GccUnixR/uasm
install -Dt "$out/share/doc/${pname}" -m0644 {Readme,History}.txt Doc/*
runHook postInstall
'';
passthru.tests.version = testers.testVersion {
package = uasm;
command = "uasm -h";
version = "v${version}";
};
meta = with lib; {
homepage = "https://www.terraspace.co.uk/uasm.html";
description = "A free MASM-compatible assembler based on JWasm";
platforms = platforms.unix;
maintainers = with maintainers; [ thiagokokada ];
license = licenses.watcom;
};
}
|