blob: 9ce72c9b2ef812d952b3431c97f17589f1679f51 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
{ lib
, stdenvNoCC
, fetchFromGitHub
, flavour ? [ "frappe" ]
, accents ? [ "blue" ]
, winDecStyles ? [ "modern" ]
}:
let
validFlavours = [ "mocha" "macchiato" "frappe" "latte" ];
validAccents = [ "rosewater" "flamingo" "pink" "mauve" "red" "maroon" "peach" "yellow" "green" "teal" "sky" "sapphire" "blue" "lavender" ];
validWinDecStyles = [ "modern" "classic" ];
installScript = ./install.sh;
in
lib.checkListOfEnum "Invalid accent, valid accents are ${toString validAccents}" validAccents accents
lib.checkListOfEnum "Invalid flavour, valid flavours are ${toString validFlavours}" validFlavours flavour
lib.checkListOfEnum "Invalid window decoration style, valid styles are ${toString validWinDecStyles}" validWinDecStyles winDecStyles
stdenvNoCC.mkDerivation rec {
pname = "kde";
version = "0.2.4";
src = fetchFromGitHub {
owner = "catppuccin";
repo = pname;
rev = "v${version}";
hash = "sha256-w77lzeSisx/PPxctMJKIdRJenq0s8HwR8gLmgNh4SH8=";
};
installPhase = ''
runHook preInstall
patchShebangs .
for WINDECSTYLE in ${toString winDecStyles}; do
for FLAVOUR in ${toString flavour}; do
for ACCENT in ${toString accents}; do
FLAVOUR=$FLAVOUR ACCENT=$ACCENT WINDECSTYLE=$WINDECSTYLE bash ${installScript}
done;
done;
done;
runHook postInstall
'';
meta = with lib; {
description = "Soothing pastel theme for KDE";
homepage = "https://github.com/catppuccin/kde";
license = licenses.mit;
maintainers = with maintainers; [ michaelBelsanti ];
};
}
|