blob: bd59ac5fa459741539b740a668c91e5efd84853d (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
{ lib, stdenv
, sway-unwrapped, swaybg
, makeWrapper, symlinkJoin, writeShellScriptBin
, withBaseWrapper ? true, extraSessionCommands ? "", dbus
, withGtkWrapper ? false, wrapGAppsHook, gdk-pixbuf
}:
assert extraSessionCommands != "" -> withBaseWrapper;
with lib;
let
baseWrapper = writeShellScriptBin "sway" ''
set -o errexit
if [ ! "$_SWAY_WRAPPER_ALREADY_EXECUTED" ]; then
export _SWAY_WRAPPER_ALREADY_EXECUTED=1
${extraSessionCommands}
fi
if [ "$DBUS_SESSION_BUS_ADDRESS" ]; then
export DBUS_SESSION_BUS_ADDRESS
exec ${sway-unwrapped}/bin/sway "$@"
else
exec ${dbus}/bin/dbus-run-session ${sway-unwrapped}/bin/sway "$@"
fi
'';
in symlinkJoin {
name = "sway-${sway-unwrapped.version}";
paths = (optional withBaseWrapper baseWrapper)
++ [ sway-unwrapped ];
nativeBuildInputs = [ makeWrapper ]
++ (optional withGtkWrapper wrapGAppsHook);
buildInputs = optional withGtkWrapper gdk-pixbuf;
postBuild = ''
# We want to run wrapProgram manually to only wrap sway and add swaybg:
export dontWrapGApps=true
${optionalString withGtkWrapper "wrapGAppsHook"}
wrapProgram $out/bin/sway \
--prefix PATH : "${swaybg}/bin" ${optionalString withGtkWrapper ''\
"''${gappsWrapperArgs[@]}"
''}
'';
passthru.providedSessions = [ "sway" ];
inherit (sway-unwrapped) meta;
}
|