1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
{ stdenv
, lib
, fetchFromGitHub
, autoreconfHook
, go-md2man
, pkg-config
, libcap
, libseccomp
, python3
, systemd
, yajl
, nixosTests
, criu
, system
}:
let
# these tests require additional permissions
disabledTests = [
"test_capabilities.py"
"test_cwd.py"
"test_detach.py"
"test_exec.py"
"test_hooks.py"
"test_hostname.py"
"test_paths.py"
"test_pid.py"
"test_pid_file.py"
"test_preserve_fds.py"
"test_resources"
"test_seccomp"
"test_start.py"
"test_uid_gid.py"
"test_update.py"
"tests_libcrun_utils"
];
in
stdenv.mkDerivation rec {
pname = "crun";
version = "0.21";
src = fetchFromGitHub {
owner = "containers";
repo = pname;
rev = version;
sha256 = "sha256-PhhaCXtWsknMsEt1F9jMfEWSl+OLQ/C/iTj7t0XuAFw=";
fetchSubmodules = true;
};
nativeBuildInputs = [ autoreconfHook go-md2man pkg-config python3 ];
buildInputs = [ libcap libseccomp systemd yajl ]
# Criu currently only builds on x86_64-linux
++ lib.optional (lib.elem system criu.meta.platforms) criu;
enableParallelBuilding = true;
# we need this before autoreconfHook does its thing in order to initialize
# config.h with the correct values
postPatch = ''
echo ${version} > .tarball-version
echo '#define GIT_VERSION "${src.rev}"' > git-version.h
${lib.concatMapStringsSep "\n" (e:
"substituteInPlace Makefile.am --replace 'tests/${e}' ''"
) disabledTests}
'';
doCheck = true;
passthru.tests = { inherit (nixosTests) podman; };
meta = with lib; {
description = "A fast and lightweight fully featured OCI runtime and C library for running containers";
license = licenses.gpl2Plus;
platforms = platforms.linux;
inherit (src.meta) homepage;
maintainers = with maintainers; [ ] ++ teams.podman.members;
};
}
|