1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
{ lib
, stdenv
, fetchFromGitHub
, testers
, cmake
, gsl
, libtool
, findutils
, llvmPackages
, mpi
, nest
, pkg-config
, boost
, python3
, readline
, autoPatchelfHook
, withPython ? false
, withMpi ? false
}:
stdenv.mkDerivation rec {
pname = "nest";
version = "3.6";
src = fetchFromGitHub {
owner = "nest";
repo = "nest-simulator";
rev = "v${version}";
hash = "sha256-sXtF4JmHYoLp0t3o4KF6R2E0qLnKrzSPMXOxVJAm+sU=";
};
postPatch = ''
patchShebangs cmake/CheckFiles/check_return_val.sh
# fix PyNEST installation path
# it expects CMAKE_INSTALL_LIBDIR to be relative
substituteInPlace cmake/ProcessOptions.cmake \
--replace "\''${CMAKE_INSTALL_LIBDIR}/python" "lib/python"
'';
nativeBuildInputs = [
cmake
pkg-config
findutils
];
buildInputs = [
gsl
readline
libtool # libltdl
boost
] ++ lib.optionals withPython [
python3
python3.pkgs.cython
] ++ lib.optional withMpi mpi
++ lib.optional stdenv.isDarwin llvmPackages.openmp;
propagatedBuildInputs = with python3.pkgs; [
numpy
];
cmakeFlags = [
"-Dwith-python=${if withPython then "ON" else "OFF"}"
"-Dwith-mpi=${if withMpi then "ON" else "OFF"}"
"-Dwith-openmp=ON"
];
postInstall = ''
# Alternative to autoPatchElf, moves libraries where
# Nest expects them to be
find $out/lib/nest -exec ln -s {} $out/lib \;
'';
passthru.tests.version = testers.testVersion {
package = nest;
command = "nest --version";
};
meta = with lib; {
description = "NEST is a command line tool for simulating neural networks";
homepage = "https://www.nest-simulator.org/";
changelog = "https://github.com/nest/nest-simulator/releases/tag/v${version}";
license = licenses.gpl2Plus;
maintainers = with maintainers; [ jiegec davidcromp ];
platforms = platforms.unix;
};
}
|