pkgs/applications/networking/instant-messengers/ratox/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

{ lib, stdenv, fetchgit, libtoxcore
, conf ? null }:

with lib;

let
  configFile = optionalString (conf!=null) (builtins.toFile "config.h" conf);

in stdenv.mkDerivation {
  pname = "ratox";
  version = "0.4.20180303";

  src = fetchgit {
    url = "git://git.2f30.org/ratox.git";
    rev = "269f7f97fb374a8f9c0b82195c21de15b81ddbbb";
    sha256 = "0bpn37h8jvsqd66fkba8ky42nydc8acawa5x31yxqlxc8mc66k74";
  };

  buildInputs = [ libtoxcore ];

  preConfigure = ''
    substituteInPlace config.mk \
      --replace '-lsodium -lopus -lvpx ' ""

    ${optionalString (conf!=null) "cp ${configFile} config.def.h"}
  '';

  makeFlags = [ "PREFIX=$(out)" ];

  meta = {
    description = "FIFO based tox client";
    homepage = "http://ratox.2f30.org/";
    license = licenses.isc;
    maintainers = with maintainers; [ ehmry ];
    platforms = platforms.linux;
  };
}