blob: 082607e4d023376737bc9c4f71eae1301287d1d4 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
{ stdenv
, lib
, callPackage
, fetchFromGitHub
, cmake
, pkg-config
, python3
, caf
, openssl
}:
let
inherit (stdenv.hostPlatform) isStatic;
src-cmake = fetchFromGitHub {
owner = "zeek";
repo = "cmake";
rev = "9f05362a5c33ed11dab37d2dedf74206d59d8f6d";
hash = "sha256-UfPPbwLJcI6+8EYLKRcBhxashEkCTJ2Gj1JOtFayot8=";
};
src-3rdparty = fetchFromGitHub {
owner = "zeek";
repo = "zeek-3rdparty";
rev = "eb87829547270eab13c223e6de58b25bc9a0282e";
hash = "sha256-AVaKcRjF5ZiSR8aPSLBzSTeWVwGWW/aSyQJcN0Yhza0=";
};
caf' = caf.overrideAttrs (old: {
version = "unstable-2022-11-17-zeek";
src = fetchFromGitHub {
owner = "zeek";
repo = "actor-framework";
rev = "dbb68b4573736d7aeb69268cc73aa766c998b3dd";
hash = "sha256-RV2mKF3B47h/hDgK/D1UJN/ll2G5rcPkHaLVY1/C/Pg=";
};
checkPhase = ''
runHook preCheck
libcaf_core/caf-core-test
libcaf_io/caf-io-test
libcaf_openssl/caf-openssl-test
libcaf_net/caf-net-test --not-suites='net.*'
runHook postCheck
'';
});
in
stdenv.mkDerivation {
pname = "zeek-broker";
version = "unstable-2023-02-01";
outputs = [ "out" "py" ];
strictDeps = true;
src = fetchFromGitHub {
owner = "zeek";
repo = "broker";
rev = "bc0205ce1fc06ddb91abb6744cb79c7eb846c23e";
hash = "sha256-bmyitJg3kRyIXm09IupLwZXbiGZfikkHcRcIexkS4/g=";
};
postUnpack = ''
rmdir $sourceRoot/cmake $sourceRoot/3rdparty
ln -s ${src-cmake} ''${sourceRoot}/cmake
ln -s ${src-3rdparty} ''${sourceRoot}/3rdparty
# Refuses to build the bindings unless this file is present, but never
# actually uses it.
touch $sourceRoot/bindings/python/3rdparty/pybind11/CMakeLists.txt
'';
patches = [
./0001-Fix-include-path-in-exported-CMake-targets.patch
];
nativeBuildInputs = [ cmake ];
buildInputs = [ openssl python3.pkgs.pybind11 ];
propagatedBuildInputs = [ caf' ];
cmakeFlags = [
"-DCAF_ROOT=${caf'}"
"-DENABLE_STATIC_ONLY:BOOL=${if isStatic then "ON" else "OFF"}"
"-DPY_MOD_INSTALL_DIR=${placeholder "py"}/${python3.sitePackages}/"
];
meta = with lib; {
description = "Zeek's Messaging Library";
homepage = "https://github.com/zeek/broker";
license = licenses.bsd3;
platforms = platforms.unix;
maintainers = with maintainers; [ tobim ];
};
}
|