blob: f7336c346bb17ad7398e82cb3efc606619e899ba (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
{ stdenv, lib, buildGoPackage, fetchFromGitHub, go-bindata }:
let
goPackagePath = "k8s.io/kops";
generic = { version, sha256, ...}@attrs:
let attrs' = builtins.removeAttrs attrs ["version" "sha256"] ; in
buildGoPackage {
pname = "kops";
inherit version;
inherit goPackagePath;
src = fetchFromGitHub {
rev = version;
owner = "kubernetes";
repo = "kops";
inherit sha256;
};
buildInputs = [go-bindata];
subPackages = ["cmd/kops"];
buildFlagsArray = ''
-ldflags=
-X k8s.io/kops.Version=${version}
-X k8s.io/kops.GitVersion=${version}
'';
preBuild = ''
(cd go/src/k8s.io/kops
go-bindata -o upup/models/bindata.go -pkg models -prefix upup/models/ upup/models/...)
'';
postInstall = ''
mkdir -p $bin/share/bash-completion/completions
mkdir -p $bin/share/zsh/site-functions
$bin/bin/kops completion bash > $bin/share/bash-completion/completions/kops
$bin/bin/kops completion zsh > $bin/share/zsh/site-functions/_kops
'';
meta = with stdenv.lib; {
description = "Easiest way to get a production Kubernetes up and running";
homepage = https://github.com/kubernetes/kops;
license = licenses.asl20;
maintainers = with maintainers; [offline zimbatm kampka];
platforms = platforms.unix;
};
} // attrs';
in rec {
mkKops = generic;
kops_1_12 = mkKops {
version = "1.12.3";
sha256 = "0rpbaz54l5v1z7ab5kpxcb4jyakkl5ysgz1sxajqmw2d6dvf7xly";
};
kops_1_13 = mkKops {
version = "1.13.1";
sha256 = "0knypbrpipxplgdg6r0r6ycsj7w46virmzwn5s4sdim0y8d2ppyb";
};
}
|