blob: b0b7e8a08eb4bd26e1322892f85e2c9e46cc11e5 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
{ lib
, stdenv
, buildGoModule
, buildGoPackage
, fetchFromGitHub
, installShellFiles
, pkgsBuildBuild
}:
let
# Argo can package a static server in the CLI using the `staticfiles` go module.
# We build the CLI without the static server for simplicity, but the tool is still required for
# compilation to succeed.
# See: https://github.com/argoproj/argo/blob/d7690e32faf2ac5842468831daf1443283703c25/Makefile#L117
staticfiles = pkgsBuildBuild.buildGoModule rec {
name = "staticfiles";
src = fetchFromGitHub {
owner = "bouk";
repo = "staticfiles";
rev = "827d7f6389cd410d0aa3f3d472a4838557bf53dd";
hash = "sha256-wchj5KjhTmhc4XVW0sRFCcyx5W9am8TNAIhej3WFWXU=";
};
vendorHash = null;
excludedPackages = [ "./example" ];
preBuild = ''
cp ${./staticfiles.go.mod} go.mod
'';
ldflags = [ "-s" "-w" ];
};
in
buildGoModule rec {
pname = "argo";
version = "3.5.0";
src = fetchFromGitHub {
owner = "argoproj";
repo = "argo";
rev = "refs/tags/v${version}";
hash = "sha256-3MwSiI21j2tMqdDInK7Q+QDMiFCophJyNXMOXMwJeEQ=";
};
vendorHash = "sha256-Zh/r4/+x67C1yXGW/R+FYKiGFaGPEV//Sg9cWwVIMxI=";
doCheck = false;
subPackages = [
"cmd/argo"
];
nativeBuildInputs = [
installShellFiles
];
preBuild = ''
mkdir -p ui/dist/app
echo "Built without static files" > ui/dist/app/index.html
${staticfiles}/bin/staticfiles -o server/static/files.go ui/dist/app
'';
ldflags = [
"-s"
"-w"
"-X github.com/argoproj/argo-workflows/v3.buildDate=unknown"
"-X github.com/argoproj/argo-workflows/v3.gitCommit=${src.rev}"
"-X github.com/argoproj/argo-workflows/v3.gitTag=${src.rev}"
"-X github.com/argoproj/argo-workflows/v3.gitTreeState=clean"
"-X github.com/argoproj/argo-workflows/v3.version=${version}"
];
postInstall = ''
for shell in bash zsh; do
${if (stdenv.buildPlatform == stdenv.hostPlatform)
then "$out/bin/argo"
else "${pkgsBuildBuild.argo}/bin/argo"
} completion $shell > argo.$shell
installShellCompletion argo.$shell
done
'';
meta = with lib; {
description = "Container native workflow engine for Kubernetes";
homepage = "https://github.com/argoproj/argo";
changelog = "https://github.com/argoproj/argo-workflows/blob/v${version}/CHANGELOG.md";
license = licenses.asl20;
maintainers = with maintainers; [ groodt ];
platforms = platforms.unix;
};
}
|