blob: 76af55c5082a2060666701c49d5c3648ecfd18b3 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
{ lib, stdenv, fetchurl, fetchsvn, makeWrapper, unzip, jre, libXxf86vm
, extraJavaOpts ? "-Djosm.restart=true -Djava.net.useSystemProxies=true"
}:
let
pname = "josm";
version = "18004";
srcs = {
jar = fetchurl {
url = "https://josm.openstreetmap.de/download/josm-snapshot-${version}.jar";
sha256 = "sha256-Cd+/sE6A0MddHeAxy3gx7ev+9UR3ZNcR0tCTmdX2FtY=";
};
macosx = fetchurl {
url = "https://josm.openstreetmap.de/download/macosx/josm-macos-${version}-java16.zip";
sha256 = "sha256-QSVh8043K/f7gPEjosGo/DNj1d75LUFwf6EMeHk68fM=";
};
pkg = fetchsvn {
url = "https://josm.openstreetmap.de/svn/trunk/native/linux/tested";
rev = version;
sha256 = "sha256-Ic6RtQPqpQIci1IbKgTcFmLfMdPxSVybrEAk+ttM0j8=";
};
};
in
stdenv.mkDerivation rec {
inherit pname version;
dontUnpack = true;
nativeBuildInputs = [ makeWrapper ];
buildInputs = lib.optionals (!stdenv.isDarwin) [ jre ];
installPhase =
if stdenv.isDarwin then ''
mkdir -p $out/Applications
${unzip}/bin/unzip ${srcs.macosx} 'JOSM.app/*' -d $out/Applications
'' else ''
install -Dm644 ${srcs.jar} $out/share/josm/josm.jar
cp -R ${srcs.pkg}/usr/share $out
# Add libXxf86vm to path because it is needed by at least Kendzi3D plugin
makeWrapper ${jre}/bin/java $out/bin/josm \
--add-flags "${extraJavaOpts} -jar $out/share/josm/josm.jar" \
--prefix LD_LIBRARY_PATH ":" '${libXxf86vm}/lib'
'';
meta = with lib; {
description = "An extensible editor for OpenStreetMap";
homepage = "https://josm.openstreetmap.de/";
changelog = "https://josm.openstreetmap.de/wiki/Changelog";
license = licenses.gpl2Plus;
maintainers = with maintainers; [ rycee sikmir ];
platforms = platforms.all;
};
}
|