blob: 0e7155f374d1c5a067a5dec4aac278a72da2d12d (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
{stdenv, python3Packages, gettext, qt5, fetchFromGitHub}:
python3Packages.buildPythonApplication rec {
pname = "dupeguru";
version = "4.0.4";
format = "other";
src = fetchFromGitHub {
owner = "arsenetar";
repo = "dupeguru";
rev = "${version}";
sha256 = "0ma4f1c6vmpz8gi4sdy43x1ik7wh42wayvk1iq520d3i714kfcpy";
fetchSubmodules = true;
};
nativeBuildInputs = [
gettext
python3Packages.pyqt5
qt5.wrapQtAppsHook
];
pythonPath = with python3Packages; [
pyqt5
send2trash
sphinx
polib
hsaudiotag3k
];
makeFlags = [
"PREFIX=${placeholder ''out''}"
"NO_VENV=1"
];
# TODO: package pytest-monkeyplus for running tests
# https://github.com/NixOS/nixpkgs/pull/75054/files#r357690123
doCheck = false;
# Avoid double wrapping Python programs.
dontWrapQtApps = true;
preFixup = ''
# TODO: A bug in python wrapper
# see https://github.com/NixOS/nixpkgs/pull/75054#discussion_r357656916
makeWrapperArgs="''${qtWrapperArgs[@]}"
'';
postFixup = ''
# Executable in $out/bin is a symlink to $out/share/dupeguru/run.py
# so wrapPythonPrograms hook does not handle it automatically.
wrapPythonProgramsIn "$out/share/dupeguru" "$out $pythonPath"
'';
meta = with stdenv.lib; {
description = "GUI tool to find duplicate files in a system";
homepage = "https://github.com/arsenetar/dupeguru";
license = licenses.bsd3;
platforms = platforms.linux;
maintainers = [ maintainers.novoxudonoser ];
};
}
|