blob: 0cca2ea6cd35ff9649fd84c42d8d701ba838c879 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
{ lib
, stdenvNoCC
, fetchzip
, copyDesktopItems
, jdk11
, makeDesktopItem
, makeWrapper
, unzip
, xdg-utils
}:
stdenvNoCC.mkDerivation rec {
pname = "irpf";
version = "2022-1.4";
src = let
year = lib.head (lib.splitVersion version);
in fetchzip {
url = "https://downloadirpf.receita.fazenda.gov.br/irpf/${year}/irpf/arquivos/IRPF${version}.zip";
sha256 = "sha256-AKBcBkoPDBknUOyndf9hNigzDHjjgi2v0n1Rs+//j/8=";
};
nativeBuildInputs = [ unzip makeWrapper copyDesktopItems ];
desktopItems = [
(makeDesktopItem rec {
name = pname;
exec = pname;
icon = "rfb64";
desktopName = "Imposto de Renda Pessoa Física";
comment = "Programa Oficial da Receita para elaboração do IRPF";
categories = [ "Office" ];
})
];
installPhase = ''
runHook preInstall
BASEDIR="$out/share/${pname}"
mkdir -p "$BASEDIR"
cp -r help lib lib-modulos "$BASEDIR"
install -Dm755 irpf.jar "$BASEDIR/${pname}.jar"
install -Dm644 Leia-me.htm offline.png online.png pgd-updater.jar "$BASEDIR"
makeWrapper ${jdk11}/bin/java $out/bin/${pname} \
--add-flags "-Dawt.useSystemAAFontSettings=on" \
--add-flags "-Dswing.aatext=true" \
--add-flags "-jar $BASEDIR/${pname}.jar" \
--prefix PATH : ${lib.makeBinPath [ xdg-utils ]} \
--set _JAVA_AWT_WM_NONREPARENTING 1 \
--set AWT_TOOLKIT MToolkit
mkdir -p $out/share/pixmaps
unzip -j lib/ppgd-icones-4.0.jar icones/rfb64.png -d $out/share/pixmaps
runHook postInstall
'';
meta = with lib; {
description = "Brazillian government application for reporting income tax";
longDescription = ''
Brazillian government application for reporting income tax.
IRFP - Imposto de Renda Pessoa Física - Receita Federal do Brasil.
'';
homepage = "https://www.gov.br/receitafederal/pt-br";
license = licenses.unfree;
platforms = platforms.all;
maintainers = with maintainers; [ atila ];
};
}
|