pkgs/applications/editors/emacs-modes/emacs-libvterm/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

{ stdenv, fetchFromGitHub, cmake, emacs, libvterm-neovim }:

let
  emacsSources = stdenv.mkDerivation {
    name = emacs.name + "-sources";
    src = emacs.src;

    dontConfigure = true;
    dontBuild = true;
    doCheck = false;
    fixupPhase = ":";

    installPhase = ''
      mkdir -p $out
      cp -a * $out
    '';

  };

  libvterm = libvterm-neovim.overrideAttrs(old: rec {
    pname = "libvterm-neovim";
    version = "2019-04-27";
    name = pname + "-" + version;
    src = fetchFromGitHub {
      owner = "neovim";
      repo = "libvterm";
      rev = "89675ffdda615ffc3f29d1c47a933f4f44183364";
      sha256 = "0l9ixbj516vl41v78fi302ws655xawl7s94gmx1kb3fmfgamqisy";
    };
  });


in stdenv.mkDerivation rec {
  name = "emacs-libvterm-${version}";
  version = "unstable-2019-04-28";

  src = fetchFromGitHub {
    owner = "akermu";
    repo = "emacs-libvterm";
    rev = "6adcedf3e4aaadeeaff97437044fba17aeb466d4";
    sha256 = "1j6qr5bmajig3idhwsaa3zm72w13q9zn77z2dlrhhx3p4bbds3f8";
  };

  nativeBuildInputs = [ cmake ];
  buildInputs = [ emacs libvterm ];

  cmakeFlags = [
    "-DEMACS_SOURCE=${emacsSources}"
    "-DUSE_SYSTEM_LIBVTERM=True"
  ];

  installPhase = ''
    install -d $out/share/emacs/site-lisp
    install ../*.el $out/share/emacs/site-lisp
    install ../*.so $out/share/emacs/site-lisp
  '';
}