pkgs/applications/audio/axoloti/libusb1.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

{ stdenv, lib, fetchurl, pkg-config, systemd ? null, libobjc, IOKit, fetchpatch }:

stdenv.mkDerivation rec {
  name = "libusb-1.0.19";

  src = fetchurl {
    url = "mirror://sourceforge/libusb/${name}.tar.bz2";
    sha256 = "0h38p9rxfpg9vkrbyb120i1diq57qcln82h5fr7hvy82c20jql3c";
  };

  outputs = [ "out" "dev" ]; # get rid of propagating systemd closure

  buildInputs = [ pkg-config ];
  propagatedBuildInputs =
    lib.optional stdenv.isLinux systemd ++
    lib.optionals stdenv.isDarwin [ libobjc IOKit ];

  patches = [
    (fetchpatch {
      name = "libusb.stdfu.patch";
      url = "https://raw.githubusercontent.com/axoloti/axoloti/1.0.12/platform_linux/src/libusb.stdfu.patch";
      sha256 = "194j7j61i4q6x0ihm9ms8dxd4vliw20n2rj6cm9h17qzdl9xr33d";
    })
  ];

  NIX_LDFLAGS = lib.optionalString stdenv.isLinux "-lgcc_s";

  preFixup = lib.optionalString stdenv.isLinux ''
    sed 's,-ludev,-L${lib.getLib systemd}/lib -ludev,' -i $out/lib/libusb-1.0.la
  '';

  meta = with lib; {
    homepage = "http://www.libusb.info";
    description = "User-space USB library";
    platforms = platforms.unix;
    license = licenses.lgpl21;
  };
}