blob: e110a5c86101f5a3128e3aecd1357b66bc86db99 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
{ config, lib, pkgs, ... }:
with lib;
let
cfg = config.services.morty;
in
{
###### interface
options = {
services.morty = {
enable = mkEnableOption
"Morty proxy server. See https://github.com/asciimoo/morty";
ipv6 = mkOption {
type = types.bool;
default = true;
description = "Allow IPv6 HTTP requests?";
defaultText = "Allow IPv6 HTTP requests.";
};
key = mkOption {
type = types.str;
default = "";
description = ''
HMAC url validation key (hexadecimal encoded).
Leave blank to disable. Without validation key, anyone can
submit proxy requests. Leave blank to disable.
'';
defaultText = "No HMAC url validation. Generate with echo -n somevalue | openssl dgst -sha1 -hmac somekey";
};
timeout = mkOption {
type = types.int;
default = 2;
description = "Request timeout in seconds.";
defaultText = "A resource now gets 2 seconds to respond.";
};
package = mkOption {
type = types.package;
default = pkgs.morty;
defaultText = "pkgs.morty";
description = "morty package to use.";
};
port = mkOption {
type = types.int;
default = 3000;
description = "Listing port";
};
listenAddress = mkOption {
type = types.str;
default = "127.0.0.1";
description = "The address on which the service listens";
defaultText = "127.0.0.1 (localhost)";
};
};
};
###### Service definition
config = mkIf config.services.morty.enable {
users.users.morty =
{ description = "Morty user";
createHome = true;
home = "/var/lib/morty";
isSystemUser = true;
};
systemd.services.morty =
{
description = "Morty sanitizing proxy server.";
after = [ "network.target" ];
wantedBy = [ "multi-user.target" ];
serviceConfig = {
User = "morty";
ExecStart = ''${cfg.package}/bin/morty \
-listen ${cfg.listenAddress}:${toString cfg.port} \
${optionalString cfg.ipv6 "-ipv6"} \
${optionalString (cfg.key != "") "-key " + cfg.key} \
'';
};
};
environment.systemPackages = [ cfg.package ];
};
}
|