nixos/modules/services/monitoring/prometheus/exporters/unifi-poller.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

{ config, lib, pkgs, options }:

with lib;

let
  cfg = config.services.prometheus.exporters.unifi-poller;

  configFile = pkgs.writeText "prometheus-unifi-poller-exporter.json" (generators.toJSON {} {
    poller = { inherit (cfg.log) debug quiet; };
    unifi = { inherit (cfg) controllers; };
    influxdb.disable = true;
    prometheus = {
      http_listen = "${cfg.listenAddress}:${toString cfg.port}";
      report_errors = cfg.log.prometheusErrors;
    };
  });

in {
  port = 9130;

  extraOpts = {
    inherit (options.services.unifi-poller.unifi) controllers;
    log = {
      debug = mkEnableOption "debug logging including line numbers, high resolution timestamps, per-device logs.";
      quiet = mkEnableOption "startup and error logs only.";
      prometheusErrors = mkEnableOption "emitting errors to prometheus.";
    };
  };

  serviceOpts.serviceConfig = {
    ExecStart = "${pkgs.unifi-poller}/bin/unifi-poller --config ${configFile}";
    DynamicUser = false;
  };
}