1 files changed, 62 insertions, 0 deletions
diff --git a/pkgs/tools/security/gnupg/20.nix b/pkgs/tools/security/gnupg/20.nix
new file mode 100644
index 00000000000..a5fdc2e2692
--- /dev/null
+++ b/pkgs/tools/security/gnupg/20.nix
@@ -0,0 +1,62 @@
+{ fetchurl, stdenv, readline, zlib, libgpgerror, pth, libgcrypt, libassuan
+, libksba, coreutils, libiconv, pcsclite
+
+# Each of the dependencies below are optional.
+# Gnupg can be built without them at the cost of reduced functionality.
+, pinentry ? null, x11Support ? true
+, openldap ? null, bzip2 ? null, libusb ? null, curl ? null
+}:
+
+with stdenv.lib;
+
+assert x11Support -> pinentry != null;
+
+stdenv.mkDerivation rec {
+  name = "gnupg-2.0.27";
+
+  src = fetchurl {
+    url = "mirror://gnupg/gnupg/${name}.tar.bz2";
+    sha256 = "1wihx7dphacg9fy5wfj93h236lr1w5gwzh7ir3js37wi9cz6sr2p";
+  };
+
+  buildInputs
+    = [ readline zlib libgpgerror libgcrypt libassuan libksba pth
+        openldap bzip2 libusb curl libiconv ];
+
+  patchPhase = ''
+    find tests -type f | xargs sed -e 's@/bin/pwd@${coreutils}&@g' -i
+  '' + stdenv.lib.optionalString stdenv.isLinux ''
+    sed -i 's,"libpcsclite\.so[^"]*","${pcsclite}/lib/libpcsclite.so",g' scd/scdaemon.c
+  '' + stdenv.lib.optionalString stdenv.isDarwin ''
+    find . -name pcsc-wrapper.c | xargs sed -i 's/typedef unsinged int pcsc_dword_t/typedef unsigned int pcsc_dword_t/'
+  '' + ''
+    patch gl/stdint_.h < ${./clang.patch}
+  '';
+
+  configureFlags = optional x11Support "--with-pinentry-pgm=${pinentry}/bin/pinentry";
+
+  checkPhase="GNUPGHOME=`pwd` ./agent/gpg-agent --daemon make check";
+
+  doCheck = true;
+
+  meta = {
+    homepage = "http://gnupg.org/";
+    description = "free implementation of the OpenPGP standard for encrypting and signing data";
+    license = stdenv.lib.licenses.gpl3Plus;
+
+    longDescription = ''
+      GnuPG is the GNU project's complete and free implementation of
+      the OpenPGP standard as defined by RFC4880.  GnuPG allows to
+      encrypt and sign your data and communication, features a
+      versatile key management system as well as access modules for all
+      kind of public key directories.  GnuPG, also known as GPG, is a
+      command line tool with features for easy integration with other
+      applications.  A wealth of frontend applications and libraries
+      are available.  Version 2 of GnuPG also provides support for
+      S/MIME.
+    '';
+
+    maintainers = with stdenv.lib.maintainers; [ roconnor urkud ];
+    platforms = stdenv.lib.platforms.all;
+  };
+}