1 files changed, 40 insertions, 0 deletions
diff --git a/pkgs/development/python-modules/python_openzwave/default.nix b/pkgs/development/python-modules/python_openzwave/default.nix
new file mode 100644
index 00000000000..d5cf709104f
--- /dev/null
+++ b/pkgs/development/python-modules/python_openzwave/default.nix
@@ -0,0 +1,40 @@
+{ stdenv, buildPythonPackage, fetchPypi, isPy3k
+, pkgconfig
+, systemd, libyaml, openzwave, cython
+, six, pydispatcher, urwid }:
+
+buildPythonPackage rec {
+  pname = "python_openzwave";
+  version = "0.4.4";
+
+  disabled = !isPy3k;
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "17wdgwg212agj1gxb2kih4cvhjb5bprir4x446s8qwx0mz03azk2";
+    extension = "zip";
+  };
+
+  nativeBuildInputs = [ pkgconfig ];
+  buildInputs = [ systemd libyaml openzwave cython ];
+  propagatedBuildInputs = [ six urwid pydispatcher ];
+
+  # primary location for the .xml files is in /etc/openzwave so we override the
+  # /usr/local/etc lookup instead as that allows us to dump new .xml files into
+  # /etc/openzwave if needed
+  postPatch = ''
+    substituteInPlace src-lib/libopenzwave/libopenzwave.pyx \
+      --replace /usr/local/etc/openzwave ${openzwave}/etc/openzwave
+  '';
+
+  # no tests available
+  doCheck = false;
+
+  meta = with stdenv.lib; {
+    description = "Python wrapper for the OpenZWave C++ library";
+    homepage = https://github.com/OpenZWave/python-openzwave;
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ etu ];
+    inherit (openzwave.meta) platforms;
+  };
+}