1 files changed, 92 insertions, 0 deletions
diff --git a/pkgs/development/python-modules/jupyterlab-server/default.nix b/pkgs/development/python-modules/jupyterlab-server/default.nix
new file mode 100644
index 00000000000..a408137650a
--- /dev/null
+++ b/pkgs/development/python-modules/jupyterlab-server/default.nix
@@ -0,0 +1,92 @@
+{ lib
+, buildPythonPackage
+, fetchPypi
+, pythonOlder
+, hatchling
+, babel
+, importlib-metadata
+, jinja2
+, json5
+, jsonschema
+, jupyter-server
+, packaging
+, requests
+, openapi-core
+, pytest-jupyter
+, pytestCheckHook
+, requests-mock
+, ruamel-yaml
+, strict-rfc3339
+}:
+
+buildPythonPackage rec {
+  pname = "jupyterlab-server";
+  version = "2.25.1";
+  pyproject = true;
+
+  disabled = pythonOlder "3.8";
+
+  src = fetchPypi {
+    pname = "jupyterlab_server";
+    inherit version;
+    hash = "sha256-ZJEoOwAAaY6uGjjEhQeTBWDfz3RhrqABU2hpiqs03Zw=";
+  };
+
+  postPatch = ''
+    sed -i "/timeout/d" pyproject.toml
+  '';
+
+  nativeBuildInputs = [
+    hatchling
+  ];
+
+  propagatedBuildInputs = [
+    babel
+    jinja2
+    json5
+    jsonschema
+    jupyter-server
+    packaging
+    requests
+  ] ++ lib.optionals (pythonOlder "3.10") [
+    importlib-metadata
+  ];
+
+  passthru.optional-dependencies = {
+    openapi = [
+      openapi-core
+      ruamel-yaml
+    ];
+  };
+
+  nativeCheckInputs = [
+    pytest-jupyter
+    pytestCheckHook
+    requests-mock
+    strict-rfc3339
+  ] ++ passthru.optional-dependencies.openapi;
+
+  preCheck = ''
+    export HOME=$(mktemp -d)
+  '';
+
+  disabledTestPaths = [
+    # require optional language pack packages for tests
+    "tests/test_translation_api.py"
+  ];
+
+  pythonImportsCheck = [
+    "jupyterlab_server"
+    "jupyterlab_server.pytest_plugin"
+  ];
+
+  __darwinAllowLocalNetworking = true;
+
+  meta = with lib; {
+    description = "A set of server components for JupyterLab and JupyterLab like applications";
+    homepage = "https://github.com/jupyterlab/jupyterlab_server";
+    changelog = "https://github.com/jupyterlab/jupyterlab_server/blob/v${version}/CHANGELOG.md";
+    license = licenses.bsd3;
+    maintainers = lib.teams.jupyter.members;
+  };
+}