1 files changed, 45 insertions, 0 deletions
diff --git a/pkgs/development/libraries/libinput/default.nix b/pkgs/development/libraries/libinput/default.nix
new file mode 100644
index 00000000000..80ad7879e10
--- /dev/null
+++ b/pkgs/development/libraries/libinput/default.nix
@@ -0,0 +1,45 @@
+{ stdenv, fetchurl, pkgconfig
+, libevdev, mtdev, udev
+, documentationSupport ? true, doxygen ? null, graphviz ? null # Documentation
+, eventGUISupport ? false, cairo ? null, glib ? null, gtk3 ? null # GUI event viewer support
+, testsSupport ? false, check ? null, valgrind ? null
+}:
+
+assert documentationSupport -> doxygen != null && graphviz != null;
+assert eventGUISupport -> cairo != null && glib != null && gtk3 != null;
+assert testsSupport -> check != null && valgrind != null;
+
+let
+  mkFlag = optSet: flag: if optSet then "--enable-${flag}" else "--disable-${flag}";
+in
+
+with stdenv.lib;
+stdenv.mkDerivation rec {
+  name = "libinput-0.13.0";
+
+  src = fetchurl {
+    url = "http://www.freedesktop.org/software/libinput/${name}.tar.xz";
+    sha256 = "06n6ih2bfr957rprsgjxhi6f7m96wmf4kgac8y0ispsjvrzszv3c";
+  };
+
+  configureFlags = [
+    (mkFlag documentationSupport "documentation")
+    (mkFlag eventGUISupport "event-gui")
+    (mkFlag testsSupport "tests")
+  ];
+
+  nativeBuildInputs = [ pkgconfig ];
+
+  buildInputs = [ libevdev mtdev udev ]
+    ++ optionals eventGUISupport [ cairo glib gtk3 ]
+    ++ optionals documentationSupport [ doxygen graphviz ]
+    ++ optionals testsSupport [ check valgrind ];
+
+  meta = {
+    description = "Handles input devices in Wayland compositors and provides a generic X.Org input driver";
+    homepage    = http://www.freedesktop.org/wiki/Software/libinput;
+    license     = licenses.mit;
+    platforms   = platforms.unix;
+    maintainers = with maintainers; [ codyopel wkennington ];
+  };
+}