1 files changed, 40 insertions, 0 deletions
diff --git a/pkgs/desktops/gnome-3/3.24/core/gdm/default.nix b/pkgs/desktops/gnome-3/3.24/core/gdm/default.nix
new file mode 100644
index 00000000000..59f0381f2e8
--- /dev/null
+++ b/pkgs/desktops/gnome-3/3.24/core/gdm/default.nix
@@ -0,0 +1,40 @@
+{ stdenv, fetchurl, pkgconfig, glib, itstool, libxml2, xorg, dbus
+, intltool, accountsservice, libX11, gnome3, systemd, autoreconfHook
+, gtk, libcanberra_gtk3, pam, libtool, gobjectIntrospection, plymouth
+, librsvg }:
+
+stdenv.mkDerivation rec {
+  inherit (import ./src.nix fetchurl) name src;
+
+  # Only needed to make it build
+  preConfigure = ''
+    substituteInPlace ./configure --replace "/usr/bin/X" "${xorg.xorgserver.out}/bin/X"
+  '';
+
+  configureFlags = [ "--sysconfdir=/etc"
+                     "--localstatedir=/var"
+                     "--with-plymouth=yes"
+                     "--with-systemdsystemunitdir=$(out)/etc/systemd/system" ];
+
+  buildInputs = [ pkgconfig glib itstool libxml2 intltool autoreconfHook
+                  accountsservice gnome3.dconf systemd
+                  gobjectIntrospection libX11 gtk
+                  libcanberra_gtk3 pam libtool plymouth librsvg ];
+
+  enableParallelBuilding = true;
+
+  # Disable Access Control because our X does not support FamilyServerInterpreted yet
+  patches = [ ./sessions_dir.patch
+              ./gdm-x-session_extra_args.patch
+              ./gdm-session-worker_xserver-path.patch
+             ];
+
+  installFlags = [ "sysconfdir=$(out)/etc" "dbusconfdir=$(out)/etc/dbus-1/system.d" ];
+
+  meta = with stdenv.lib; {
+    homepage = https://wiki.gnome.org/Projects/GDM;
+    description = "A program that manages graphical display servers and handles graphical user logins";
+    platforms = platforms.linux;
+    maintainers = gnome3.maintainers;
+  };
+}