1 files changed, 56 insertions, 0 deletions
diff --git a/pkgs/data/themes/whitesur/default.nix b/pkgs/data/themes/whitesur/default.nix
new file mode 100644
index 00000000000..e9691eaad7d
--- /dev/null
+++ b/pkgs/data/themes/whitesur/default.nix
@@ -0,0 +1,56 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, glib
+, gnome-themes-extra
+, libxml2
+, sassc
+, util-linux
+}:
+
+stdenv.mkDerivation rec {
+  pname = "whitesur-gtk-theme";
+  version = "2021-06-23";
+
+  src = fetchFromGitHub {
+    owner = "vinceliuice";
+    repo = pname;
+    rev = version;
+    sha256 = "075fw57mv6zadq4dryn8bg2b3vq8inmisq18s758cv53pprxh9hw";
+  };
+
+  nativeBuildInputs = [
+    glib
+    libxml2
+    sassc
+    util-linux
+  ];
+
+  buildInputs = [
+    gnome-themes-extra # adwaita engine for Gtk2
+  ];
+
+  postPatch = ''
+    find -name "*.sh" -print0 | while IFS= read -r -d ''' file; do patchShebangs "$file"; done
+
+    # Do not provide `sudo`, as it is not needed in our use case of the install script
+    substituteInPlace lib-core.sh --replace '$(which sudo)' false
+  '';
+
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/share/themes
+    ./install.sh --dest $out/share/themes --alt all --theme all
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "MacOS Big Sur like theme for Gnome desktops";
+    homepage = "https://github.com/vinceliuice/WhiteSur-gtk-theme";
+    license = licenses.mit;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.romildo ];
+  };
+}