1 files changed, 79 insertions, 0 deletions
diff --git a/pkgs/by-name/us/usql/package.nix b/pkgs/by-name/us/usql/package.nix
new file mode 100644
index 00000000000..2faeda9b09b
--- /dev/null
+++ b/pkgs/by-name/us/usql/package.nix
@@ -0,0 +1,79 @@
+{ lib
+, fetchFromGitHub
+, buildGoModule
+, unixODBC
+, icu
+, nix-update-script
+, testers
+, usql
+}:
+
+buildGoModule rec {
+  pname = "usql";
+  version = "0.16.0";
+
+  src = fetchFromGitHub {
+    owner = "xo";
+    repo = "usql";
+    rev = "v${version}";
+    hash = "sha256-XfzCJOr0lOkimUKbOW0+qFNQMmYc0DBgi+0ItmEOjwE=";
+  };
+
+  buildInputs = [ unixODBC icu ];
+
+  vendorHash = "sha256-sijt6YOp1pFNhaxLIOLH90Z5ODVbWFj/mp8Csx8n+ac=";
+  proxyVendor = true;
+
+  # Exclude broken genji, hive & impala drivers (bad group)
+  # These drivers break too often and are not used.
+  #
+  # See https://github.com/xo/usql/pull/347
+  #
+  excludedPackages = [
+    "genji"
+    "hive"
+    "impala"
+  ];
+
+  # These tags and flags are copied from build.sh
+  tags = [
+    "most"
+    "sqlite_app_armor"
+    "sqlite_fts5"
+    "sqlite_introspect"
+    "sqlite_json1"
+    "sqlite_math_functions"
+    "sqlite_stat4"
+    "sqlite_userauth"
+    "sqlite_vtable"
+    "no_adodb"
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/xo/usql/text.CommandVersion=${version}"
+  ];
+
+  # All the checks currently require docker instances to run the databases.
+  doCheck = false;
+
+  passthru = {
+    updateScript = nix-update-script { };
+    tests.version = testers.testVersion {
+      inherit version;
+      package = usql;
+      command = "usql --version";
+    };
+  };
+
+  meta = with lib; {
+    description = "Universal command-line interface for SQL databases";
+    homepage = "https://github.com/xo/usql";
+    changelog = "https://github.com/xo/usql/releases/tag/v${version}";
+    license = licenses.mit;
+    mainProgram = "usql";
+    maintainers = with maintainers; [ georgyo anthonyroussel ];
+    platforms = with platforms; linux ++ darwin;
+  };
+}