1 files changed, 0 insertions, 93 deletions
diff --git a/pkgs/applications/virtualization/qemu/2.8.nix b/pkgs/applications/virtualization/qemu/2.8.nix
deleted file mode 100644
index 677386819d3..00000000000
--- a/pkgs/applications/virtualization/qemu/2.8.nix
+++ /dev/null
@@ -1,93 +0,0 @@
-{ stdenv, fetchurl, fetchpatch, python2, zlib, pkgconfig, glib
-, ncurses, perl, pixman, vde2, alsaLib, texinfo, libuuid, flex
-, bison, lzo, snappy, libaio, gnutls, nettle, curl
-, makeWrapper
-, attr, libcap, libcap_ng
-, CoreServices, Cocoa, rez, setfile
-, numaSupport ? stdenv.isLinux, numactl
-, seccompSupport ? stdenv.isLinux, libseccomp
-, pulseSupport ? !stdenv.isDarwin, libpulseaudio
-, sdlSupport ? !stdenv.isDarwin, SDL
-, vncSupport ? true, libjpeg, libpng
-, spiceSupport ? !stdenv.isDarwin, spice, spice_protocol, usbredir
-, x86Only ? false
-, nixosTestRunner ? false
-}:
-
-with stdenv.lib;
-let
-  version = "2.8.0";
-  audio = optionalString (hasSuffix "linux" stdenv.system) "alsa,"
-    + optionalString pulseSupport "pa,"
-    + optionalString sdlSupport "sdl,";
-in
-
-stdenv.mkDerivation rec {
-  name = "qemu-"  
-    + stdenv.lib.optionalString x86Only "x86-only-"
-    + stdenv.lib.optionalString nixosTestRunner "for-vm-tests-"
-    + version;
-
-  src = fetchurl {
-    url = "http://wiki.qemu.org/download/qemu-${version}.tar.bz2";
-    sha256 = "0qjy3rcrn89n42y5iz60kgr0rrl29hpnj8mq2yvbc1wrcizmvzfs";
-  };
-
-  buildInputs =
-    [ python2 zlib pkgconfig glib ncurses perl pixman
-      vde2 texinfo libuuid flex bison makeWrapper lzo snappy
-      gnutls nettle curl
-    ]
-    ++ optionals stdenv.isDarwin [ CoreServices Cocoa rez setfile ]
-    ++ optionals seccompSupport [ libseccomp ]
-    ++ optionals numaSupport [ numactl ]
-    ++ optionals pulseSupport [ libpulseaudio ]
-    ++ optionals sdlSupport [ SDL ]
-    ++ optionals vncSupport [ libjpeg libpng ]
-    ++ optionals spiceSupport [ spice_protocol spice usbredir ]
-    ++ optionals stdenv.isLinux [ alsaLib libaio libcap_ng libcap attr ];
-
-  enableParallelBuilding = true;
-
-  patches = [
-    ./no-etc-install.patch
-  ] ++ optional nixosTestRunner ./force-uid0-on-9p.patch;
-  hardeningDisable = [ "stackprotector" ];
-
-  configureFlags =
-    [ "--smbd=smbd" # use `smbd' from $PATH
-      "--audio-drv-list=${audio}"
-      "--sysconfdir=/etc"
-      "--localstatedir=/var"
-    ]
-    ++ optional numaSupport "--enable-numa"
-    ++ optional seccompSupport "--enable-seccomp"
-    ++ optional spiceSupport "--enable-spice"
-    ++ optional x86Only "--target-list=i386-softmmu,x86_64-softmmu"
-    ++ optional stdenv.isDarwin "--enable-cocoa"
-    ++ optional stdenv.isLinux "--enable-linux-aio";
-
-  postFixup =
-    ''
-      for exe in $out/bin/qemu-system-* ; do
-        paxmark m $exe
-      done
-    '';
-
-  postInstall =
-    ''
-      # Add a ‘qemu-kvm’ wrapper for compatibility/convenience.
-      p="$out/bin/qemu-system-${if stdenv.system == "x86_64-linux" then "x86_64" else "i386"}"
-      if [ -e "$p" ]; then
-        makeWrapper "$p" $out/bin/qemu-kvm --add-flags "\$([ -e /dev/kvm ] && echo -enable-kvm)"
-      fi
-    '';
-
-  meta = with stdenv.lib; {
-    homepage = http://www.qemu.org/;
-    description = "A generic and open source machine emulator and virtualizer";
-    license = licenses.gpl2Plus;
-    maintainers = with maintainers; [ viric eelco ];
-    platforms = platforms.linux ++ platforms.darwin;
-  };
-}