ntfy: use python39 and remove ntfy-webpush from python3Packages

2 files changed, 56 insertions, 5 deletions

diff --git a/pkgs/tools/misc/ntfy/default.nix b/pkgs/tools/misc/ntfy/default.nix
index e976ca5fd69..d905c92438d 100644
--- a/pkgs/tools/misc/ntfy/default.nix
+++ b/pkgs/tools/misc/ntfy/default.nix
@@ -1,9 +1,21 @@
-{ lib, python3Packages, fetchFromGitHub, fetchpatch }:
+{ lib
+, python39
+, fetchFromGitHub
+, fetchpatch
+}:
 
-python3Packages.buildPythonApplication rec {
+let
+  python = python39.override {
+    packageOverrides = self: super: {
+      ntfy-webpush = self.callPackage ./webpush.nix { };
+    };
+  };
+in python.pkgs.buildPythonApplication rec {
   pname = "ntfy";
   version = "2.7.0";
 
+  format = "setuptools";
+
   src = fetchFromGitHub {
     owner = "dschep";
     repo = "ntfy";
@@ -11,11 +23,11 @@ python3Packages.buildPythonApplication rec {
     sha256 = "09f02cn4i1l2aksb3azwfb70axqhn7d0d0vl2r6640hqr74nc1cv";
   };
 
-  checkInputs = with python3Packages; [
+  checkInputs = with python.pkgs; [
     mock
   ];
 
-  propagatedBuildInputs = with python3Packages; [
+  propagatedBuildInputs = with python.pkgs; [
     requests ruamel-yaml appdirs
     sleekxmpp dnspython
     emoji
@@ -37,7 +49,7 @@ python3Packages.buildPythonApplication rec {
   ];
 
   checkPhase = ''
-    HOME=$(mktemp -d) ${python3Packages.python.interpreter} setup.py test
+    HOME=$(mktemp -d) ${python.interpreter} setup.py test
   '';
 
   meta = with lib; {
diff --git a/pkgs/tools/misc/ntfy/webpush.nix b/pkgs/tools/misc/ntfy/webpush.nix
new file mode 100644
index 00000000000..aad5bf48a40
--- /dev/null
+++ b/pkgs/tools/misc/ntfy/webpush.nix
@@ -0,0 +1,39 @@
+{ lib
+, buildPythonPackage
+, fetchFromGitHub
+, pywebpush
+, py-vapid
+}:
+
+buildPythonPackage rec {
+  pname = "ntfy-webpush";
+  version = "0.1.3";
+
+  src = fetchFromGitHub {
+    owner = "dschep";
+    repo = "ntfy-webpush";
+    rev = "v${version}";
+    sha256 = "1dxlvq3glf8yjkn1hdk89rx1s4fi9ygg46yn866a9v7a5a83zx2n";
+  };
+
+  postPatch = ''
+    # break dependency loop
+    substituteInPlace setup.py \
+      --replace "'ntfy', " ""
+  '';
+
+  propagatedBuildInputs = [
+    pywebpush
+    py-vapid
+  ];
+
+  # no tests, just a script
+  doCheck = false;
+
+  meta = with lib; {
+    description = "cloudbell webpush notification support for ntfy";
+    homepage = "https://dschep.github.io/ntfy-webpush/";
+    license = licenses.mit;
+    maintainers = with maintainers; [ SuperSandro2000 ];
+  };
+}