Last good Nixpkgs for Weston+nouveau? archive

I came this commit hash to terwiz[m] on IRC, who is trying to figure out
what the last version of Spectrum that worked on their NUC with Nvidia
graphics is.

1 files changed, 45 insertions, 0 deletions

diff --git a/pkgs/tools/misc/csvs-to-sqlite/default.nix b/pkgs/tools/misc/csvs-to-sqlite/default.nix
new file mode 100644
index 00000000000..1deae6b3f83
--- /dev/null
+++ b/pkgs/tools/misc/csvs-to-sqlite/default.nix
@@ -0,0 +1,45 @@
+{ lib, python3, fetchFromGitHub }:
+
+let
+  # csvs-to-sqlite is currently not compatible with Click 8. See the following
+  # https://github.com/simonw/csvs-to-sqlite/issues/80
+  #
+  # Workaround the issue by providing click 7 explicitly.
+  python = python3.override {
+    packageOverrides = self: super: {
+      # Use click 7
+      click = self.callPackage ../../../development/python2-modules/click/default.nix { };
+    };
+  };
+in with python.pkgs; buildPythonApplication rec {
+  pname = "csvs-to-sqlite";
+  version = "1.2";
+  disabled = !isPy3k;
+
+  src = fetchFromGitHub {
+    owner = "simonw";
+    repo = pname;
+    rev = version;
+    sha256 = "0p99cg76d3s7jxvigh5ad04dzhmr6g62qzzh4i6h7x9aiyvdhvk4";
+  };
+
+  propagatedBuildInputs = [
+    click
+    dateparser
+    pandas
+    py-lru-cache
+    six
+  ];
+
+  checkInputs = [
+    pytestCheckHook
+  ];
+
+  meta = with lib; {
+    description = "Convert CSV files into a SQLite database";
+    homepage = "https://github.com/simonw/csvs-to-sqlite";
+    license = licenses.asl20;
+    maintainers = [ maintainers.costrouc ];
+  };
+
+}