Merge pull request #17947 from RamKromberg/init/rc

rc: init at 1.7.4

1 files changed, 42 insertions, 0 deletions

diff --git a/pkgs/shells/rc/default.nix b/pkgs/shells/rc/default.nix
new file mode 100644
index 00000000000..298c4a1c32f
--- /dev/null
+++ b/pkgs/shells/rc/default.nix
@@ -0,0 +1,42 @@
+{ stdenv, fetchurl, autoreconfHook
+, ncurses #acinclude.m4 wants headers for tgetent().
+, historySupport ? false
+, readline ? null
+}:
+
+stdenv.mkDerivation rec {
+  name = "rc-${version}";
+  version = "1.7.4";
+
+  src = fetchurl {
+    url = "http://static.tobold.org/rc/rc-${version}.tar.gz";
+    sha256 = "1n5zz6d6z4z6s3fwa0pscqqawy561k4xfnmi91i626hcvls67ljy";
+  };
+
+  nativeBuildInputs = [ autoreconfHook ];
+  buildInputs = [ ncurses ]
+    ++ stdenv.lib.optionals (readline != null) [ readline ];
+
+  configureFlags = [
+    "--enable-def-interp=${stdenv.shell}" #183
+    ] ++ stdenv.lib.optionals historySupport [ "--with-history" ]
+    ++ stdenv.lib.optionals (readline != null) [ "--with-edit=readline" ];
+
+  prePatch = ''
+    substituteInPlace configure.ac \
+      --replace "date -I" "echo 2015-05-13" #reproducible-build
+  '';
+
+  passthru = {
+    shellPath = "/bin/rc";
+  };
+
+  meta = with stdenv.lib; {
+    description = "The Plan 9 shell";
+    longDescription = "Byron Rakitzis' UNIX reimplementation of Tom Duff's Plan 9 shell.";
+    homepage = http://tobold.org/article/rc;
+    license = with licenses; zlib;
+    maintainers = with maintainers; [ ramkromberg ];
+    platforms = with platforms; all;
+  };
+}