fzf-zsh: init at unstable-2019-09-09

Simple `fzf` wrapper which provides a way nicer interface for ZSH's
<C-r> search. When using oh-my-zsh it can be enabled like this:

``` nix
{ pkgs, ... }: {
  programs.zsh = {
    enable = true;
    ohMyZsh = {
      enable = true;
      customPkgs = [ pkgs.fzf-zsh ];
      plugins = [ "fzf-zsh" ];
    };
  };
}
```

1 files changed, 37 insertions, 0 deletions

diff --git a/pkgs/shells/zsh/fzf-zsh/default.nix b/pkgs/shells/zsh/fzf-zsh/default.nix
new file mode 100644
index 00000000000..e97ef1074f1
--- /dev/null
+++ b/pkgs/shells/zsh/fzf-zsh/default.nix
@@ -0,0 +1,37 @@
+{ stdenv, fetchFromGitHub, fzf }:
+
+stdenv.mkDerivation rec {
+  pname = "fzf-zsh-unstable";
+  version = "2019-09-09";
+
+  src = fetchFromGitHub {
+    owner = "Wyntau";
+    repo = "fzf-zsh";
+    rev = "829d7e40cc437dce8a6e234e259bbd4065e87124";
+    sha256 = "1irjmxhcg1fm4g8p3psjqk7sz5qhj5kw73pyhv91njvpdhn9l26z";
+  };
+
+  postPatch = ''
+    substituteInPlace fzf-zsh.plugin.zsh \
+      --replace \
+        'fzf_path="$( cd "$fzf_zsh_path/../fzf/" && pwd )"' \
+        "fzf_path=${fzf}" \
+      --replace \
+        '$fzf_path/shell' \
+        '${fzf}/share/fzf'
+  '';
+
+  dontBuild = true;
+
+  installPhase = ''
+    install -Dm0644 fzf-zsh.plugin.zsh $out/share/zsh/plugins/fzf-zsh/fzf-zsh.plugin.zsh
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = https://github.com/wyntau/fzf-zsh;
+    description = "wrap fzf to use in oh-my-zsh";
+    license = licenses.mit;
+    maintainers = with maintainers; [ ma27 ];
+    platforms = platforms.unix;
+  };
+}