qqwing: init at 1.3.4

1 files changed, 35 insertions, 0 deletions

diff --git a/pkgs/games/qqwing/default.nix b/pkgs/games/qqwing/default.nix
new file mode 100644
index 00000000000..30c9ca66d10
--- /dev/null
+++ b/pkgs/games/qqwing/default.nix
@@ -0,0 +1,35 @@
+{ stdenv, fetchFromGitHub, perl, autoconf, automake, libtool }:
+
+stdenv.mkDerivation rec {
+  name = "qqwing-${version}";
+  version = "1.3.4";
+
+  src = fetchFromGitHub {
+    owner = "stephenostermiller";
+    repo = "qqwing";
+    rev = "v${version}";
+    sha256 = "1qq0vi4ch4y3a5fb1ncr0yzkj3mbvdiwa3d51qpabq94sh0cz09i";
+  };
+
+  postPatch = ''
+    for file in "src-first-comment.pl" "src_neaten.pl"; do
+      substituteInPlace "build/$file" \
+        --replace "#!/usr/bin/perl" "#!${perl}/bin/perl"
+    done
+
+    substituteInPlace "build/cpp_install.sh" \
+      --replace "sudo " ""
+  '';
+
+  buildInputs = [ perl autoconf automake libtool ];
+
+  makeFlags = [ "prefix=$(out)" "tgz" ];
+
+  meta = with stdenv.lib; {
+    homepage = https://qqwing.com;
+    description = "Sudoku generating and solving software";
+    license = licenses.gpl2;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ jgeerds ];
+  };
+}